DOS 7 & MAME .37b9
This old P200 needs as much help as it can get, and running pure DOS with an older MAME release definitely helps.  I really liked the .37b9 release for it's stability, plus Asteroids still works!

Autoexec.bat menu
I originally saw this idea on the DOS MAME support page (mameworld.net/dosmame).   I have been using a customized version of Jason's autoexec.bat file for my upright, but I have almost completely rewritten it for the Happy Hour cabinet, basically retaining the original intent of the file.  This menu is handy because you can load Windows, change emulators, and automatically shutdown the cabinet without the use of a mouse or keyboard.  Below is a copy of my autoexec.bat file. (I'm not a DOS expert at all, so if anyone sees a better way to do something, please let me know!)

@echo off
rem
rem Happy Hour DOS menu file
rem
rem Happy Hour's controls mapped as:
rem -------------------------
rem JOYSTICK
rem [P1 UP] - UP
rem [P1 DOWN] - DOWN
rem [P1 LEFT] - LEFT
rem [P1 RIGHT] - RIGHT
rem -------------------------
rem BUTTONS (CONTROL PANEL)
rem [P1 START] - 1
rem [P2 START] - 2
rem [A] - LCTRL
rem [B] - ALT
rem [C] - SPACE
rem [Pause] - P
rem [Esc] - ESCAPE
rem -------------------------
rem BUTTONS (REMOTE)
rem [Power] - SYSTEM POWER SWITCH
rem [Tab] - TAB (MAME Configuration)
rem [Enter] - ENTER
rem

:common
mode 80
echo Starting boot sequence...
echo.
set tmp=c:\temp
set temp=c:\temp
c:\sound\setupsa /s > null
c:\optimous\ctmouse /1 > null

:diskcheck
if exist c:\shutdown.dat goto badexit
copy c:\autoexec.bat c:\shutdown.dat > null
goto aos

:badexit
mode 80
@echo
echo ***********************************
echo ** INCORRECT SHUTDOWN DETECTED!! **
echo ***********************************
echo.
echo.
echo Disk must be checked...
echo.
echo.
pause
scandisk /all /autofix /nosummary
if not exist c:\shutdown.dat copy c:\autoexec.bat c:\shutdown.dat > null

:aos
echo.
echo. Entering Arcade...
echo.
c:\dos\smartdrv /x /r > null
cd c:\arcadeos
arcadeos
c:\dos\smartdrv /c > null

:main
mode 80
echo.
echo.
echo *****************
echo **  Main Menu  **
echo *****************
echo.
echo.
echo [P1 START] Go back to the Arcade
echo.
echo.
echo [P2 START] Power off (automatic in 60 seconds)
echo.
echo.
echo.
echo.
echo [Pause Button] Enter the Advanced Menu
echo.
choice /c:p21 /n /t:2,60
if errorlevel 3 goto aos
if errorlevel 2 goto off
if errorlevel 1 goto advanced

:off
del c:\shutdown.dat > null
c:\atxoff

:advanced
mode 80
echo.
echo.
echo *********************
echo **  Advanced Menu  **
echo *********************
echo.
echo.
echo [P1 Start] Start Windows 98
echo.
echo.
echo [P2 Start] Load Atari 2600 emulator
echo.
echo.
echo.
echo.
echo [Pause Button] Return to the Main Menu
echo.
choice /c:12p /n
if errorlevel 3 goto main
if errorlevel 2 goto atari
if errorlevel 1 goto win

:atari
c:
cd c:\pcae
pcae
pause
goto main

:win
echo Launching Windows 98. Please wait...
del c:\shutdown.dat > null
win

:end

Automatic power off
Also found on the DOS MAME support site is a file called "atxoff.com" that will shutdown your computer when run.  An atx form factor motherboard is required.   The admin remote for Happy Hour is only required to start the cabinet, and through the use of this autoexec.bat file, the cabinet will shut down automatically.